Coupled oscillators

breed [nodes node]

links-own [ weight ]

to setup
  clear-all
  ;; creates all the nodes
  set-default-shape nodes "circle"
  create-nodes nb-nodes [ setxy random-xcor random-ycor set size 0.125 ]
  ;; link the nodes
  link-nodes
  ;; set simulation time to 0
  reset-ticks
end 

to go
  ifelse draw-trajectories [  ;; draw the trajectories?
    ask nodes [pen-down]
  ][
    ask nodes [pen-up]
  ]
  ifelse draw-links [  ;; show the trajectories?
    ask links [show-link]
  ][
    ask links [hide-link]
  ]
  
  move-nodes
  tick
end 

to move-nodes
  ask nodes
  [
    ;; x and y coordinates of the nodes
    let z-real xcor
    let z-imag ycor
    
    ;; f(z) = (lambda + i*omega - |z|^2)*z
    let mod-z-sq (modulus z-real z-imag) * (modulus z-real z-imag) ;; modulus(z) square
    let fz-real (rmult (lambda - mod-z-sq) omega z-real z-imag)
    let fz-imag (imult (lambda - mod-z-sq) omega z-real z-imag)
    
    ;; interaction of the neighbors: [SUM_j (xj - xi) * wj]/nb_links
    let coupling-real (sum [weight * [xcor - z-real] of other-end] of my-links) / (count my-links)
    let coupling-imag (sum [weight * [ycor - z-imag] of other-end] of my-links) / (count my-links)
    
    ;; euler algorithm
    setxy (xcor + (fz-real + sigma * coupling-real) * dt) (ycor + (fz-imag + sigma * coupling-imag) * dt)
  ]
end 




;; create the links among nodes (Watts and Strogatz algorithm), add weight and color

to link-nodes  
  ;; create a regular lattice
  ask turtles [
    let n 1
    while [ n <= K ]
    [
      ifelse who < (count turtles - K)
      [
        ifelse (random-float 1) < beta
        [
          random-link
        ]
        [
          normal-link n
        ]
      ]
      [
        normal-link n
      ]
      set n (n + 1)
    ]
  ]
end 

to normal-link [n]
  create-link-with turtle ((who + n) mod count turtles)
  [ 
    set color blue
    set weight 1
  ]
end  

;; create a link with another 'not-yet linked' node whose id > caller id 

to random-link  
  let myid who
  let other-node one-of other turtles with [(who > myid) and (not link-neighbor? turtle myid)]
  if other-node != nobody
  [
    create-link-with other-node
    [
      set color red
      set weight -1
    ]
  ]
end 

;;; Real and Imaginary Arithmetic Operators

;;; real part of the multiplication (a+ib)*(c+id) = (ac-bd) + i(ad+cb)
;;; returns the real part (ac-bd)

to-report rmult [real1 imaginary1 real2 imaginary2]
  report real1 * real2 - imaginary1 * imaginary2
end 

;;; imaginary part of the multiplication (a+ib)*(c+id) = (ac-bd) + i(ad+cb)
;;; returns the imaginary part (ad+cb)

to-report imult [real1 imaginary1 real2 imaginary2]
  report real1 * imaginary2 + real2 * imaginary1
end 

;;; returns the modulus of a complex number a+ib

to-report modulus [real imaginary]
  report sqrt (real ^ 2 + imaginary ^ 2)
end