Bug Hunt Speeds

2 collaborators

Uri Wilensky (Author)

WHAT IS IT?

This is a natural/artificial selection model that shows the result of two competing forces on natural selection of the speed of prey. Which force dominates depends on the behavior of predators.

One force is that predators that chase prey, tend to catch slower moving prey more often, thereby selecting for prey that are faster over many generations of offspring.

Another force is that predators who wait for their prey without moving, tend to catch prey that are moving faster more often, thereby selecting for prey that are slower over many generations of offspring.

By also adjusting whether bugs try to avoid the predator and the predictability of their motion, a different one of these competing forces will tend to dominate the selective pressure on the population.

HOW IT WORKS

You assume the role of a predator amongst a population of bugs. To begin your pursuit of bugs as a predator, press SETUP to create a population of bugs, determined by six times the INITIAL-BUGS-EACH-SPEED slider. These bugs that are created are randomly distributed around the world and assigned a speed.

When you press GO the bugs begin to move at their designated speeds. As they move around, try to eat as many bugs as fast as you can by clicking on them. Alternatively, you may hold the mouse button down and move the predator over the bugs.

The six different speeds that a bug might move at are distributed amongst six different sub-populations of the bugs. These speeds are inherited. With each bug you eat, a new bug is randomly chosen from the population to produce one offspring. The offspring is an exact duplicate of the parent (in its speed and location). The creation of new offspring keeps the overall population of the bugs constant.

Initially there are equal numbers of each sub-population of bug (e.g. ten bugs at each of the 6 speeds). Over time, however, as you eat bugs, the distribution of the bugs will change as shown in the "Number of bugs" histogram. In the histogram, you might see the distribution shift to the left (showing that more slow bugs are surviving) or to the right (showing that more fast bugs are surviving). Sometimes one sub-population of a single speed of bug will be exterminated. At this point, no other bugs of this speed can be created in the population.

HOW TO USE IT

INITIAL-BUGS-EACH-SPEED is the number of bugs you start with in each of the six sub-populations. The overall population of bugs is determined by multiplying this value by 6.

SHOW-COLORS? helps you apply or remove color visualization based on the speed of the bugs. When turned on, it shows 6 distinct colors for the 6 different speeds a bug might have. These color settings correspond to the plot pen colors in the graphs. When turned off, each bug is colored gray. This prevents the predator (the model player) from unintentionally selecting bugs based on color.

NUMBER OF BUGS is a histogram showing the distribution of bugs at different speeds.

BUGS CAUGHT is a histogram showing the historical record of the distribution of bugs caught at different speeds.

WIGGLE?, when set to "on" adds a small amount of random twist in the motion of the bugs as they move forward each time step.

FLEE?, when set to "on" has bugs turn around (to face in the opposite direction) when they detect your mouse click (as a predator) in their detection cone (an arc of 120 degrees that has a range of 2 units). Bugs can detect the predator only in this arc in front of them, and so will not react when caught from behind.

THINGS TO NOTICE

The CURRENT BUGS histogram tends to shift right (increasing average speed) if you assume the role of chasing easy prey.

The CURRENT BUGS histogram tends to shift left (decreasing average speed) if you assume the role of waiting for prey come to you. The same effect can also be achieved by moving the predator around the world randomly.

THINGS TO TRY

Set the model up with INITIAL-BUGS-EACH-SPEED set to 1. Slow the model down and watch where new bugs come from when you eat a bug. You should see a new bug hatch from one of the five remaining and it should be moving at the same speed as its parent.

Wait in one location for the bugs to come to you by placing the predator in one location and holding down the mouse button. All bugs that run into you will be eaten.

Chase bugs around trying to catch the bug nearest you at any one time by holding the mouse button down and moving the predator around the view after the nearest bug.

EXTENDING THE MODEL

A HubNet version of the model with adjustable starting populations of bugs would help show what happens when two or more competitors assume similar vs. different hunting strategies on the same population at the same time.

RELATED MODELS

Bug Hunt Camouflage

CREDITS AND REFERENCES

Inspired by EvoDots software:
http://faculty.washington.edu/~herronjc/SoftwareFolder/EvoDots.html

HOW TO CITE

If you mention this model in a publication, we ask that you include these citations for the model itself and for the NetLogo software:

Novak, M. and Wilensky, U. (2005). NetLogo Bug Hunt Speeds model. http://ccl.northwestern.edu/netlogo/models/BugHuntSpeeds. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.
Wilensky, U. (1999). NetLogo. http://ccl.northwestern.edu/netlogo/. Center for Connected Learning and Computer-Based Modeling, Northwestern Institute on Complex Systems, Northwestern University, Evanston, IL.

COPYRIGHT AND LICENSE

CC BY-NC-SA 3.0

This work is licensed under the Creative Commons Attribution-NonCommercial-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-nc-sa/3.0/ or send a letter to Creative Commons, 559 Nathan Abbott Way, Stanford, California 94305, USA.

Commercial licenses are also available. To inquire about commercial licenses, please contact Uri Wilensky at uri@northwestern.edu.

Comments and Questions

Click to Run Model

breed [predators predator]
breed [bugs bug]
bugs-own [
  speed    ;; either 1, 2, 3, 4, 5, or 6
]

globals [
    total-speed-6-caught         ;; keeps track of the number of bugs caught with speed of 6
    total-speed-5-caught         ;; keeps track of the number of bugs caught with speed of 5
    total-speed-4-caught         ;; keeps track of the number of bugs caught with speed of 4
    total-speed-3-caught         ;; keeps track of the number of bugs caught with speed of 3
    total-speed-2-caught         ;; keeps track of the number of bugs caught with speed of 2
    total-speed-1-caught         ;; keeps track of the number of bugs caught with speed of 1
]

to setup
  clear-all
  set   total-speed-6-caught 0
  set   total-speed-5-caught 0
  set   total-speed-4-caught 0
  set   total-speed-3-caught 0
  set   total-speed-2-caught 0
  set   total-speed-1-caught 0
  set-default-shape bugs "bug"
  set-default-shape predators "bird"
  ask patches [ set pcolor white ]   ;; white background
  foreach [1 2 3 4 5 6] [
    create-bugs initial-bugs-each-speed [ set speed ? ]
  ]
  ask bugs [
    setxy random-xcor random-ycor
    set-color
  ]
  ;; the predator breed contains one turtle that is used to represent
  ;; a predator of the bugs (a bird)
  create-predators 1 [
    set shape "bird"
    set color black
    set size 1.5
    set heading 315
    hide-turtle
  ]
  reset-ticks
end 

to go
  ;; use EVERY to limit the overall speed of the model
  every 0.03 [
    check-caught
    move-predator
    ;; recolor the bugs in case the user changed SPEED-COLOR-MAP
    ask bugs [ set-color move-bugs]
    ;; advance the clock without plotting
    tick-advance 1
    ;; plotting takes time, so only plot every 10 ticks
    if ticks mod 10 = 0 [ update-plots ]
  ]
end 

;;;;;;;;;;;;;;;;;;;;;
;; Runtime Procedures
;;;;;;;;;;;;;;;;;;;;;

to move-bugs
    let candidate-predator nobody
    let target-heading 0

    ask bugs [
       if wiggle? [right (random-float 5 - random-float 5)]
       fd speed * 0.001

       ifelse flee? [
         ifelse any? predators in-cone 2 120 [
           set candidate-predator one-of predators in-cone 2  120
           set target-heading 180 + towards candidate-predator

           set heading target-heading
           set label "!"
         ]
         [set label ""]
       ]
       [set label ""]
     ]
end 

to move-predator
  ask predators [
    setxy mouse-xcor mouse-ycor
    ;; only show the predator if the mouse pointer is
    ;; actually inside the view
    set hidden? not mouse-inside?
  ]
end 

to check-caught
  if not mouse-down? or not mouse-inside? [ stop ]
  let prey [bugs in-radius (size / 2)] of one-of predators
  ;; no prey here? oh well
  if not any? prey [ stop ]
  ;; eat only one of the bugs at the mouse location
  ask one-of prey [
    if speed = 6 [ set total-speed-6-caught total-speed-6-caught + 1 ]
    if speed = 5 [ set total-speed-5-caught total-speed-5-caught + 1 ]
    if speed = 4 [ set total-speed-4-caught total-speed-4-caught + 1 ]
    if speed = 3 [ set total-speed-3-caught total-speed-3-caught + 1 ]
    if speed = 2 [ set total-speed-2-caught total-speed-2-caught + 1 ]
    if speed = 1 [ set total-speed-1-caught total-speed-1-caught + 1 ]
    die
  ]
  ;; replace the eaten bug with a random offspring from the remaining population
  ask one-of bugs [ hatch 1 [ rt random 360 ] ]
end 

to set-color  ;; turtle procedure
  ifelse show-colors? 
    [ set color item (speed - 1) [violet blue green brown orange red] ]
    [ set color gray]
end 


; Copyright 2005 Uri Wilensky.
; See Info tab for full copyright and license.

There are 15 versions of this model.

Uploaded by	When	Description	Download
Uri Wilensky	over 11 years ago	Updated to NetLogo 5.0.4	Download this version
Uri Wilensky	about 12 years ago	Updated version tag	Download this version
Uri Wilensky	about 12 years ago	Updated to version from NetLogo 5.0.3 distribution	Download this version
Uri Wilensky	almost 13 years ago	Updated to NetLogo 5.0	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Updated from NetLogo 4.1	Download this version
Uri Wilensky	over 14 years ago	Model from NetLogo distribution	Download this version
Uri Wilensky	over 14 years ago	Model from NetLogo distribution	Download this version
Uri Wilensky	over 14 years ago	Bug Hunt Speeds	Download this version

Attached files

File	Type	Description	Last updated
Bug Hunt Speeds.png	preview	Preview for 'Bug Hunt Speeds'	over 11 years ago, by Uri Wilensky	Download

This model does not have any ancestors.

This model does not have any descendants.

NetLogo