Wolf Sheep Stride Inheritance

globals [
  max-energy           ;; the maximum amount of energy any animal can have
  min-energy           ;; the minimum amount of energy an animal needs to reproduce
  max-stride           ;; the maximum stride length, the minimum stride length is 0,
                       ;; the stride will always be between these limits
  wolf-gain-from-food  ;; energy units wolves get for eating
  sheep-gain-from-food ;; energy units sheep get for eating
  sheep-reproduce      ;; probability that sheep will reproduce at each time step
  wolf-reproduce       ;; probability that wolves will reproduce at each time step
  grass-regrowth-time  ;; number of ticks before eaten grass regrows.
]

breed [sheep a-sheep]
breed [wolves wolf]

turtles-own [ energy stride-length ]
patches-own [ countdown ]  ;; patches countdown until they regrow

to setup
  clear-all
  ;; initialize constant values
  set max-stride 3
  set min-energy 200
  set max-energy 500
  set wolf-gain-from-food 20
  set sheep-gain-from-food 20
  set sheep-reproduce 5
  set wolf-reproduce 6
  set grass-regrowth-time 138

  ;; setup the grass
  ask patches [ set pcolor green ]
  ask patches [
    set countdown random grass-regrowth-time ;; initialize grass grow clocks randomly
    if random 2 = 0  ;;half the patches start out with grass
      [ set pcolor brown ]
  ]

  set-default-shape sheep "sheep"
  create-sheep initial-number-sheep  ;; create the sheep, then initialize their variables
  [
    set color white
    set stride-length initial-sheep-stride
    set size max-stride  ;; easier to see
    set energy random max-energy
    setxy random-xcor random-ycor
  ]

  set-default-shape wolves "wolf"
  create-wolves initial-number-wolves  ;; create the wolves, then initialize their variables
  [
    set color black
    set stride-length initial-wolf-stride
    set size max-stride  ;; easier to see
    set energy random max-energy
    setxy random-xcor random-ycor
  ]
  reset-ticks
end 

to go
  if not any? turtles [ stop ]
  ask sheep [
    move
    ;; sheep always loose 0.5 units of energy each tick
    set energy energy - 0.5
    ;; if larger strides use more energy
    ;; also deduct the energy for the distance moved
    if stride-length-penalty?
    [ set energy energy - stride-length ]
    eat-grass
    maybe-die
    reproduce-sheep
  ]
  ask wolves [
    move
    ;; wolves always loose 0.5 units of energy each tick
    set energy energy - 0.5
    ;; if larger strides use more energy
    ;; also deduct the energy for the distance moved
    if stride-length-penalty?
    [ set energy energy - stride-length ]
    catch-sheep
    maybe-die
    reproduce-wolves
  ]
  ask patches [ grow-grass ]
  tick
end 

to move  ;; turtle procedure
  rt random-float 50
  lt random-float 50
  fd stride-length
end 

to eat-grass  ;; sheep procedure
  ;; sheep eat grass, turn the patch brown
  if pcolor = green [
    set pcolor brown
    set energy energy + sheep-gain-from-food  ;; sheep gain energy by eating
    if energy > max-energy
    [ set energy max-energy ]
  ]
end 

to reproduce-sheep  ;; sheep procedure
  reproduce sheep-reproduce sheep-stride-length-drift
end 

to reproduce-wolves  ;; wolf procedure
  reproduce wolf-reproduce wolf-stride-length-drift
end 

to reproduce [reproduction-chance drift] ;; turtle procedure
  ;; throw "dice" to see if you will reproduce
  if random-float 100 < reproduction-chance and energy > min-energy [
    set energy (energy / 2 )  ;; divide energy between parent and offspring
    hatch 1 [
      rt random-float 360
      fd 1
      ;; mutate the stride length based on the drift for this breed
      set stride-length mutated-stride-length drift
    ]
  ]
end 

to-report mutated-stride-length [drift] ;; turtle reporter
  let l stride-length + random-float drift - random-float drift
  ;; keep the stride lengths within the accepted bounds
  if l < 0
  [ report 0 ]
  if stride-length > max-stride
  [ report max-stride ]
  report l
end 

to catch-sheep  ;; wolf procedure
  let prey one-of sheep-here
  if prey != nobody
  [ ask prey [ die ]
    set energy energy + wolf-gain-from-food
    if energy > max-energy [set energy max-energy]
  ]
end 

to maybe-die  ;; turtle procedure
  ;; when energy dips below zero, die
  if energy < 0 [ die ]
end 

to grow-grass  ;; patch procedure
  ;; countdown on brown patches, if reach 0, grow some grass
  if pcolor = brown [
    ifelse countdown <= 0
      [ set pcolor green
        set countdown grass-regrowth-time ]
      [ set countdown countdown - 1 ]
  ]
end 


; Copyright 2006 Uri Wilensky.
; See Info tab for full copyright and license.